Tutorial Cara Konfigurasi Load Balancing 2 ISP Metode PCC Pada Router Mikrotik

Tutorial Cara Konfigurasi Load Balancing 2 ISP Metode PCC Pada Mikrotik - Load balancing merupakan sebuah teknik yang digunakan untuk membagi traffic melalui 2 atau lebih jalur koneksi secara seimbang dan merata, tujuan dari load balancing yaitu untuk mengoptimalkan throughput, mengurangi respone time, dan juga menghindari overload atau penumpukan traffic pada salah satu jalur koneksi (link) yang dapat menyebabkan koneksi menjadi down.

Syarat untuk mengkonfigurasi load balancing pada router yaitu harus memiliki 2 atau lebih jalur koneksi (link) untuk menuju ke network lain, misalnya saja router yang terhubung ke jaringan internet melalui beberapa ISP (Internet Service Provider).

Sederhananya, load balancing adalah cara yang bisa diterapkan jika kamu berlangganan internet melalui 2 ISP yang berbeda, namun menginginkan agar koneksi internet dari kedua ISP tersebut masuk ke dalam satu router yang sama.

Misalnya kamu berlangganan internet dari ISP A dan ISP B masing-masing sebesar 5 Mbps. Lalu kamu ingin agar keduanya aktif secara bersamaan guna mengurangi penumpukan traffic yang ada di jaringan lokal, dalam kondisi seperti ini kamu bisa memanfaatkan load balancing sebagai solusinya.

Cara Setting Load Balance 2 ISP Dengan Metode PCC

Pada tutorial ini saya akan membagikan langkah-langkah cara mengkonfigurasi load balancing pada router mikrotik metode PCC dengan menggunakan 2 link ISP, bandwidth yang digunakan yaitu masing-masing sebesar 5Mbps. Berikut topologi yang saya gunakan.

Kondisi dari topologi diatas yaitu sebagai berikut :

1. Router yang digunakan yaitu tipe RB951Ui-2HnD
2. Interface ether1 terhubung ke ISP-1
3. Interface ether2 terhubung ke ISP-2
4. Interface ether3 terhubung ke switch sebagai gateway untuk jaringan lokal

Jika kondisi di jaringan kamu tidak sama, silahkan disesuaikan saja ya, sekarang saatnya kita konfig load balance-nya, buka New Terminal mikrotik kemudian paste script-script dibawah ini.

#1. Tambahkan Konfigurasi IP address 

Pertama, kita tambahkan alamat IP pada masing-masing interface router, yaitu ether1 dan ether2 untuk WAN, sedangkan ether3 untuk LAN.

/ip address
add address=192.168.90.2/30 comment=ISP-1 interface=ether1 network=192.168.90.0
add address=192.168.91.2/30 comment=ISP-2 interface=ether2 network=192.168.91.0
add address=192.168.1.1/24 comment="Local Network" interface=ether3 network=192.168.1.0

#2. Konfigurasi DNS Resolver

Kedua, tambahkan konfigurasi DNS, tujuannya agar router dapat menjangkau semua alamat domain yang ada di internet. Tanpa konfigurasi DNS maka router hanya bisa menjangkau alamat IP saja (Gak bisa internetan).

/ip dns
set allow-remote-requests=yes servers=8.8.8.8,8.8.4.4

#3. Konfigurasi Mangle Untuk PCC

Ketiga, tambahkan konfigurasi mangle untuk menandai setiap koneksi yang masuk ke dalam router melalui interface ether1 dan ether2, ini ditentukan dari chain yang dipakai yaitu input dan juga action mark connection.

/ip firewall mangle
add action=mark-connection chain=input connection-state=new in-interface=ether1 new-connection-mark=ISP-1 passthrough=yes
add action=mark-connection chain=input connection-state=new in-interface=ether2 new-connection-mark=ISP-2 passthrough=yes

Rule mangle di atas akan menandai koneksi yang masuk dari ether1 sebagai connection-mark=ISP-1, dan koneksi yang masuk melalui ether2 akan ditandai sebagai connection-mark=ISP-2, dari situ kita bisa memetakan koneksi yang keluar (chain output) dari router melalui masing-masing interface dengan action mark-routing.

add action=mark-routing chain=output connection-mark=ISP-1 new-routing-mark=Jalur-1 passthrough=no
add action=mark-routing chain=output connection-mark=ISP-2 new-routing-mark=Jalur-2 passthrough=no

Nah ini yang paling penting dari load balancing metode PCC, PCC (Per Connection Classifier) adalah sebuah fitur pada router mikrotik untuk melakukan tracking koneksi yang masuk maupun keluar melewati router berdasarkan kriteria tertentu.

Metode PCC yang akan kita gunakan kali ini yaitu untuk mengklasifikasikan koneksi yang berasal dari interface lokal (ether3) berdasarkan address and port.

add action=mark-connection chain=prerouting dst-address-type=!local in-interface=ether3 new-connection-mark=ISP-1 passthrough=yes \
    per-connection-classifier=both-addresses-and-ports:2/0
add action=mark-connection chain=prerouting dst-address-type=!local in-interface=ether3 new-connection-mark=ISP-2 passthrough=yes \
    per-connection-classifier=both-addresses-and-ports:2/1

Kemudian petakan koneksi yang berasal dari interface lokal (ether3) yang akan keluar meninggalkan router melalui masing-masing interface WAN yaitu ether1 dan ether2.

add action=mark-routing chain=prerouting connection-mark=ISP-1 in-interface=ether3 new-routing-mark=Jalur-1 passthrough=yes
add action=mark-routing chain=prerouting connection-mark=ISP-2 in-interface=ether3 new-routing-mark=Jalur-2 passthrough=yes

#4. Tambahkan Rule NAT Untuk Client

Agar client yang berada dibawah router dapat terhubung ke jaringan internet, maka kita harus menambahkan network address translation (NAT) masquerade.

/ip firewall nat
add action=masquerade chain=srcnat out-interface=ether1
add action=masquerade chain=srcnat out-interface=ether2

#5. Tambahkan Entri Routing

Entri routing yang harus kita input ke dalam table routing terbagi menjadi 2 jenis entri routing. Pertama, yaitu untuk menentukan apakah sebuah koneksi harus melalui jalur ISP-1 atau melalui jalur ISP-2.

Parameter routing-mark ini merupakan routing-mark yang sudah kita buat sebelumnya pada mangle.

/ip route
add check-gateway=ping distance=1 gateway=192.168.90.1 routing-mark=Jalur-1
add check-gateway=ping distance=2 gateway=192.168.91.1 routing-mark=Jalur-2

Kedua, yaitu berfungsi sebagai skema failover apabila salah satu link mengalami gangguan (down), maka semua traffic akan dialihkan ke link yang masih aktif.

add distance=1 gateway=192.168.90.1
add distance=2 gateway=192.168.91.1

Sampai disini konfigurasi load balancing metode PCC sudah selesai, efek load balancing biasanya baru terasa apabila traffic di jaringan lokal sudah mengalami peningkatan (full traffic), untuk memastikan load balancing sudah berfungsi dengan baik atau belum, kamu bisa mengeceknya di menu Interfaces.

Demikian tutorial cara setting load balance di mikrotik metode PCC, silahkan dishare ke teman-teman kamu sob jika tutorial ini dirasa bermanfaat, terimakasih.